## 7.1 Lexical conventions

#### Blanks

The following characters are considered as blanks: space, horizontal tabulation, carriage return, line feed and form feed. Blanks are ignored, but they separate adjacent identifiers, literals and keywords that would otherwise be confused as one single identifier, literal or keyword.

#### Comments

Comments are introduced by the two characters (*, with no intervening blanks, and terminated by the characters *), with no intervening blanks. Comments are treated as blank characters. Comments do not occur inside string or character literals. Nested comments are handled correctly.

#### Identifiers

ident | ::= | ( letter ∣ _ ) { letter ∣ 0 … 9 ∣ _ ∣ ' }
capitalized-ident | ::= | (A … Z) { letter ∣ 0 … 9 ∣ _ ∣ ' }
lowercase-ident | ::= | (a … z ∣ _) { letter ∣ 0 … 9 ∣ _ ∣ ' }
letter | ::= | A … Z ∣ a … z

Identifiers are sequences of letters, digits, _ (the underscore character), and ' (the single quote), starting with a letter or an underscore. Letters contain at least the 52 lowercase and uppercase letters from the ASCII set. The current implementation also recognizes as letters some characters from the ISO 8859-1 set (characters 192–214 and 216–222 as uppercase letters; characters 223–246 and 248–255 as lowercase letters). This feature is deprecated and should be avoided for future compatibility.

All characters in an identifier are meaningful. The current implementation accepts identifiers up to 16000000 characters in length.

In many places, OCaml makes a distinction between capitalized identifiers and identifiers that begin with a lowercase letter. The underscore character is considered a lowercase letter for this purpose.

#### Integer literals

integer-literal | ::= | [-] (0…9) { 0…9 ∣ _ }
| ∣ | [-] (0x∣ 0X) (0…9∣ A…F∣ a…f) { 0…9∣ A…F∣ a…f∣ _ }
| ∣ | [-] (0o∣ 0O) (0…7) { 0…7∣ _ }
| ∣ | [-] (0b∣ 0B) (0…1) { 0…1∣ _ }
int32-literal | ::= | integer-literal l
int64-literal | ::= | integer-literal L
nativeint-literal | ::= | integer-literal n

An integer literal is a sequence of one or more digits, optionally preceded by a minus sign. By default, integer literals are in decimal (radix 10). The following prefixes select a different radix:

Prefix | Radix
0x, 0X | hexadecimal (radix 16)
0o, 0O | octal (radix 8)
0b, 0B | binary (radix 2)

(The initial 0 is the digit zero; the O for octal is the letter O.) An integer literal can be followed by one of the letters l, L or n to indicate that this integer has type int32, int64 or nativeint respectively, instead of the default type int for integer literals. The interpretation of integer literals that fall outside the range of representable integer values is undefined.

For convenience and readability, underscore characters (_) are accepted (and ignored) within integer literals.

#### Floating-point literals

float-literal | ::= | [-] (0…9) { 0…9∣ _ } [. { 0…9∣ _ }] [(e∣ E) [+∣ -] (0…9) { 0…9∣ _ }]
| ∣ | [-] (0x∣ 0X) (0…9∣ A…F∣ a…f) { 0…9∣ A…F∣ a…f∣ _ } [. { 0…9∣ A…F∣ a…f∣ _ }] [(p∣ P) [+∣ -] (0…9) { 0…9∣ _ }]

Floating-point decimal literals consist in an integer part, a fractional part and an exponent part. The integer part is a sequence of one or more digits, optionally preceded by a minus sign. The fractional part is a decimal point followed by zero, one or more digits. The exponent part is the character e or E followed by an optional + or - sign, followed by one or more digits. It is interpreted as a power of 10. The fractional part or the exponent part can be omitted but not both, to avoid ambiguity with integer literals. The interpretation of floating-point literals that fall outside the range of representable floating-point values is undefined.

Floating-point hexadecimal literals are denoted with the 0x or 0X prefix. The syntax is similar to that of floating-point decimal literals, with the following differences. The integer part and the fractional part use hexadecimal digits. The exponent part starts with the character p or P. It is written in decimal and interpreted as a power of 2.

For convenience and readability, underscore characters (_) are accepted (and ignored) within floating-point literals.

#### Character literals

char-literal | ::= | ' regular-char '
| ∣ | ' escape-sequence '
escape-sequence | ::= | \ ( \ ∣ " ∣ ' ∣ n ∣ t ∣ b ∣ r ∣ space )
| ∣ | \ (0…9) (0…9) (0…9)
| ∣ | \x (0…9∣ A…F∣ a…f) (0…9∣ A…F∣ a…f)
| ∣ | \o (0…3) (0…7) (0…7)

Character literals are delimited by ' (single quote) characters. The two single quotes enclose either one character different from ' and \, or one of the escape sequences below:

Sequence | Character denoted
\\ | backslash (\)
\" | double quote (")
\' | single quote (')
\n | linefeed (LF)
\r | carriage return (CR)
\t | horizontal tabulation (TAB)
\b | backspace (BS)
\space | space (SPC)
\ddd | the character with ASCII code ddd in decimal
\xhh | the character with ASCII code hh in hexadecimal
\oooo | the character with ASCII code ooo in octal

#### String literals

string-literal | ::= | " { string-character } "
| ∣ | { quoted-string-id | { any-char } | quoted-string-id }
quoted-string-id | ::= | { a...z ∣ _ }
string-character | ::= | regular-string-char
| ∣ | escape-sequence
| ∣ | \u{ { 0…9∣ A…F∣ a…f }+ }
| ∣ | \ newline { space ∣ tab }

String literals are delimited by " (double quote) characters. The two double quotes enclose a sequence of either characters different from " and \, or escape sequences from the table given above for character literals, or a Unicode character escape sequence.

A Unicode character escape sequence is substituted by the UTF-8 encoding of the specified Unicode scalar value. The Unicode scalar value, an integer in the ranges 0x0000...0xD7FF or 0xE000...0x10FFFF, is defined using 1 to 6 hexadecimal digits; leading zeros are allowed.

To allow splitting long string literals across lines, the sequence \newline spaces-or-tabs (a backslash at the end of a line followed by any number of spaces and horizontal tabulations at the beginning of the next line) is ignored inside string literals.

Quoted string literals provide an alternative lexical syntax for string literals. They are useful to represent strings of arbitrary content without escaping. Quoted strings are delimited by a matching pair of { quoted-string-id | and | quoted-string-id } with the same quoted-string-id on both sides. Quoted strings do not interpret any character in a special way but requires that the sequence | quoted-string-id } does not occur in the string itself. The identifier quoted-string-id is a (possibly empty) sequence of lowercase letters and underscores that can be freely chosen to avoid such issue (e.g. {|hello|}, {ext|hello {|world|}|ext}, ...).

The current implementation places practically no restrictions on the length of string literals.

#### Naming labels

To avoid ambiguities, naming labels in expressions cannot just be defined syntactically as the sequence of the three tokens ~, ident and :, and have to be defined at the lexical level.

label-name | ::= | lowercase-ident
label | ::= | ~ label-name :
optlabel | ::= | ? label-name :

Naming labels come in two flavours: label for normal arguments and optlabel for optional ones. They are simply distinguished by their first character, either ~ or ?.

Despite label and optlabel being lexical entities in expressions, their expansions ~ label-name : and ? label-name : will be used in grammars, for the sake of readability. Note also that inside type expressions, this expansion can be taken literally, i.e. there are really 3 tokens, with optional blanks between them.

#### Prefix and infix symbols

infix-symbol | ::= | (= ∣ < ∣ > ∣ @ ∣ ^ ∣ | ∣ & ∣ + ∣ - ∣ * ∣ / ∣ $ ∣ %) { operator-char }
| ∣ | # { operator-char }+
prefix-symbol | ::= | ! { operator-char }
| ∣ | (? ∣ ~) { operator-char }+
operator-char | ::= | ! ∣ $ ∣ % ∣ & ∣ * ∣ + ∣ - ∣ . ∣ / ∣ : ∣ < ∣ = ∣ > ∣ ? ∣ @ ∣ ^ ∣ | ∣ ~

See also the following language extensions: extension operators and extended indexing operators.

Sequences of “operator characters”, such as <=> or !!, are read as a single token from the infix-symbol or prefix-symbol class. These symbols are parsed as prefix and infix operators inside expressions, but otherwise behave like normal identifiers.

#### Keywords

The identifiers below are reserved as keywords, and cannot be employed otherwise:

          and         as          assert      asr         begin       class
          constraint  do          done        downto      else        end
          exception   external    false       for         fun         function
          functor     if          in          include     inherit     initializer
          land        lazy        let         lor         lsl         lsr
          lxor        match       method      mod         module      mutable
          new         nonrec      object      of          open        or
          private     rec         sig         struct      then        to
          true        try         type        val         virtual     when
          while       with

The following character sequences are also keywords:

        !=    #     &     &&    '     (     )     *     +     ,     -
        -.    ->    .     ..    .~    :     ::    :=    :>    ;     ;;
        <     <-    =     >     >]    >}    ?     [     [<    [>    [|
        ]     _     `     {     {<    |     |]    ||    }     ~

Note that the following identifiers are keywords of the Camlp4 extensions and should be avoided for compatibility reasons.

        parser    value    $     $$    $:    <:    <<    >>    ??

#### Ambiguities

Lexical ambiguities are resolved according to the “longest match” rule: when a character sequence can be decomposed into two tokens in several different ways, the decomposition retained is the one with the longest first token.

#### Line number directives

linenum-directive | ::= | # {0 … 9}+
| ∣ | # {0 … 9}+ " { string-character } "

Preprocessors that generate OCaml source code can insert line number directives in their output so that error messages produced by the compiler contain line numbers and file names referring to the source file before preprocessing, instead of after preprocessing. A line number directive is composed of a # (sharp sign), followed by a positive integer (the source line number), optionally followed by a character string (the source file name). Line number directives are treated as blanks during lexical analysis.