main.qml Example File | Qt Quick Controls 5.6

Qt 5.6 | Qt Quick Controls | Qt Quick Controls - Touch Gallery | main.qml Example File

Qt 5.6.2 Reference Documentation

# main.qml Example File

touch/main.qml

      /****************************************************************************
      **
      ** Copyright (C) 2015 The Qt Company Ltd.
      ** Contact: http://www.qt.io/licensing/
      **
      ** This file is part of the examples of the Qt Toolkit.
      **
      ** $QT_BEGIN_LICENSE:BSD$
      ** You may use this file under the terms of the BSD license as follows:
      **
      ** "Redistribution and use in source and binary forms, with or without
      ** modification, are permitted provided that the following conditions are
      ** met:
      **   * Redistributions of source code must retain the above copyright
      **     notice, this list of conditions and the following disclaimer.
      **   * Redistributions in binary form must reproduce the above copyright
      **     notice, this list of conditions and the following disclaimer in
      **     the documentation and/or other materials provided with the
      **     distribution.
      **   * Neither the name of The Qt Company Ltd nor the names of its
      **     contributors may be used to endorse or promote products derived
      **     from this software without specific prior written permission.
      **
      **
      ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
      ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
      ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
      ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
      ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
      ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
      ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
      ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
      ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
      ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
      ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
      **
      ** $QT_END_LICENSE$
      **
      ****************************************************************************/

      import QtQuick 2.2
      import QtQuick.Controls 1.2
      import "content"

      ApplicationWindow {
          visible: true
          width: 800
          height: 1280

          Rectangle {
              color: "#212126"
              anchors.fill: parent
          }

          toolBar: BorderImage {
              border.bottom: 8
              source: "images/toolbar.png"
              width: parent.width
              height: 100

              Rectangle {
                  id: backButton
                  width: opacity ? 60 : 0
                  anchors.left: parent.left
                  anchors.leftMargin: 20
                  opacity: stackView.depth > 1 ? 1 : 0
                  anchors.verticalCenter: parent.verticalCenter
                  antialiasing: true
                  height: 60
                  radius: 4
                  color: backmouse.pressed ? "#222" : "transparent"
                  Behavior on opacity { NumberAnimation{} }
                  Image {
                      anchors.verticalCenter: parent.verticalCenter
                      source: "images/navigation_previous_item.png"
                  }
                  MouseArea {
                      id: backmouse
                      anchors.fill: parent
                      anchors.margins: -10
                      onClicked: stackView.pop()
                  }
              }

              Text {
                  font.pixelSize: 42
                  Behavior on x { NumberAnimation{ easing.type: Easing.OutCubic} }
                  x: backButton.x + backButton.width + 20
                  anchors.verticalCenter: parent.verticalCenter
                  color: "white"
                  text: "Widget Gallery"
              }
          }

          ListModel {
              id: pageModel
              ListElement {
                  title: "Buttons"
                  page: "content/ButtonPage.qml"
              }
              ListElement {
                  title: "Sliders"
                  page: "content/SliderPage.qml"
              }
              ListElement {
                  title: "ProgressBar"
                  page: "content/ProgressBarPage.qml"
              }
              ListElement {
                  title: "Tabs"
                  page: "content/TabBarPage.qml"
              }
              ListElement {
                  title: "TextInput"
                  page: "content/TextInputPage.qml"
              }
              ListElement {
                  title: "List"
                  page: "content/ListPage.qml"
              }
          }

          StackView {
              id: stackView
              anchors.fill: parent
              // Implements back key navigation
              focus: true
              Keys.onReleased: if (event.key === Qt.Key_Back && stackView.depth > 1) {
                                   stackView.pop();
                                   event.accepted = true;
                               }

              initialItem: Item {
                  width: parent.width
                  height: parent.height
                  ListView {
                      model: pageModel
                      anchors.fill: parent
                      delegate: AndroidDelegate {
                          text: title
                          onClicked: stackView.push(Qt.resolvedUrl(page))
                      }
                  }
              }
          }

      }