# GoogleTest

This module defines functions to help use the Google Test infrastructure.

`gtest_add_tests`

  Automatically add tests with CTest by scanning source code for Google Test macros:

      gtest_add_tests(TARGET target
                      [SOURCES src1...]
                      [EXTRA_ARGS arg1...]
                      [WORKING_DIRECTORY dir]
                      [TEST_PREFIX prefix]
                      [TEST_SUFFIX suffix]
                      [SKIP_DEPENDENCY]
                      [TEST_LIST outVar]
      )

  `TARGET target`
    This must be a known CMake target. CMake will substitute the location of the built executable when running the test.
  `SOURCES src1...`
    When provided, only the listed files will be scanned for test cases. If this option is not given, the `SOURCES` property of the specified `target` will be used to obtain the list of sources.
  `EXTRA_ARGS arg1...`
    Any extra arguments to pass on the command line to each test case.
  `WORKING_DIRECTORY dir`
    Specifies the directory in which to run the discovered test cases. If this option is not provided, the current binary directory is used.
  `TEST_PREFIX prefix`
    Allows the specified `prefix` to be prepended to the name of each discovered test case. This can be useful when the same source files are being used in multiple calls to `gtest_add_test()` but with different `EXTRA_ARGS`.
  `TEST_SUFFIX suffix`
    Similar to `TEST_PREFIX` except the `suffix` is appended to the name of every discovered test case. Both `TEST_PREFIX` and `TEST_SUFFIX` can be specified.
  `SKIP_DEPENDENCY`
    Normally, the function creates a dependency which will cause CMake to be re-run if any of the sources being scanned are changed. This is to ensure that the list of discovered tests is updated. If this behavior is not desired (as may be the case while actually writing the test cases), this option can be used to prevent the dependency from being added.
  `TEST_LIST outVar`
    The variable named by `outVar` will be populated in the calling scope with the list of discovered test cases. This allows the caller to do things like manipulate test properties of the discovered tests.

      include(GoogleTest)
      add_executable(FooTest FooUnitTest.cxx)
      gtest_add_tests(TARGET      FooTest
                      TEST_SUFFIX .noArgs
                      TEST_LIST   noArgsTests
      )
      gtest_add_tests(TARGET      FooTest
                      EXTRA_ARGS  --someArg someValue
                      TEST_SUFFIX .withArgs
                      TEST_LIST   withArgsTests
      )
      set_tests_properties(${noArgsTests}   PROPERTIES TIMEOUT 10)
      set_tests_properties(${withArgsTests} PROPERTIES TIMEOUT 20)

  For backward compatibility reasons, the following form is also supported:

      gtest_add_tests(exe args files...)

  `exe`
    The path to the test executable or the name of a CMake target.
  `args`
    A ;-list of extra arguments to be passed to executable. The entire list must be passed as a single argument. Enclose it in quotes, or pass `""` for no arguments.
  `files...`
    A list of source files to search for tests and test fixtures. Alternatively, use `AUTO` to specify that `exe` is the name of a CMake executable target whose sources should be scanned.

      include(GoogleTest)
      set(FooTestArgs --foo 1 --bar 2)
      add_executable(FooTest FooUnitTest.cxx)
      gtest_add_tests(FooTest "${FooTestArgs}" AUTO)